Autor Tema: Poner modos automaticos cuando se cambian varios nick de forma seguida.  (Leído 3614 veces)

0 Usuarios y 1 Visitante están viendo este tema.

Desconectado Hanna

  • Miembro Junior
  • **
  • Mensajes: 66
  • Karma: +13/-4
Hola.

Estoy intentando hacer una pequeña de protección automática, para cuando ataquen clones y les de por cambiarse de nick dentro den canal.

Cuando pase esto:

Citar
jdkfb es ahora tnqwqwg
jhknp es ahora foekxr
wkfdqut es ahora aqvxdi
fcphiv es ahora fahuvxt
vcdqao es ahora rnavrr
juinrq es ahora solzrk

El canal ponga lo modos N y W y ponga el modo +j 3:1, y cuando pase 30min el mismo bot quite los modos puestos.

Código: [Seleccionar]
on 1:nick: {
    if (%Nick_Flood. [ $+ [ $nick ] ] == $null) {
      set -u4 %Nick_Flood [ $+ [ $nick ] ] 0
    }
    else {
      inc %Nick_Flood [ $+ [ $nick ] ]
    }
    if (%Nick_Flooder. [ $+ [ $nick ] ] == 2) {
     timerene 1 5 .mode #sevilla +N | .timerjoin 1 5 mode #Sevilla +j 3:1 | .timerww 1 5 mode #Sevilla +W | .timerdelete mode #Sevilla -NWj
    }
  }

Un saludo.

Muchas gracias de antemano.

Desconectado Quetzalcoatl

  • Miembro de pleno derecho
  • ***
  • Mensajes: 160
  • Karma: +226/-2
  • HipercomputoHipermegared
    • elchatirc
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #1 en: Abril 17, 2020, 11:02:17 pm »
Hola Hanna

No entiendo o veo la pregunta, pero mirando tu código veo que No consideraste que el evento on Nick, no te da el nombre del canal y solo el $nick y $newnick, para ello debes revisar si el nick esta en #sevilla, con lo que respecta a tu variable de  %Nick_Flood.$nick, pero al crearla o incrementarla el .(punto) no se lo agregas y queda como  %Nick_Flood$nick y en los modos los aplicas todos en un diferente timer, pudiendo agruparlos en uno solo como
 timerene 1 5 .mode #sevilla +NWj 3:1 pero aunque es un ataque si se pone así, el timer se reiniciara continuamente, para eso habrá que agregar una variable de control si ya se cumplió un nick con los tres cambios, en cuanto a .timerdelete mode #Sevilla -NWj se ve bien, pero olvidaste ponerle el tiempo, quizás te seria útil esto:

Código: [Seleccionar]
;==== Inicio del comprobador de cambios de nicks rapidos.
on 1:nick: {
  if ($nick !ison #sevilla) { return }
  if (%Nick_Flood-cambio. [ $+ [ $nick ] ] == $null) { set -u4 %Nick_Flood-cambio. [ $+ [ $nick ] ] 0 }
  inc %Nick_Flood-cambio. [ $+ [ $nick ] ]
  if ((%Nick_Flood-cambio. [ $+ [ $nick ] ] == 3) && (%Nick_Flood-cambio.#sevilla != 1)) {
     set -u60 %Nick_Flood-cambio.#sevilla 1
    .timer-INICIO-FloodCambio 1 5 .mode #sevilla +NWj 3:1 | .timer-FIN-FloodCambio 1 60 mode #Sevilla -NWj
  }
}
;==== EOF

igual se le podría agregar un ban -uk a su host en ves del cambio de modos y/o poner un if ($ial($nick,0) = 3) { aqui la sanción}  en un evento on join para permitir 2 clones.

Saludos

PD: los cambios de modos de -NWj se aplican después de 60 del primer cambio detectado(3 veces que el nick se cambio) de nick en menos de 4s, deje el retraso de 5s en la colocación de modos como lo tenias antes.
« última modificación: Abril 17, 2020, 11:08:37 pm por Quetzalcoatl »

Desconectado Hanna

  • Miembro Junior
  • **
  • Mensajes: 66
  • Karma: +13/-4
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #2 en: Abril 17, 2020, 11:26:34 pm »
Hola.

Me puede explicar mal, ahora que leo, lo que queria es que si hacen en menos de 3 segundos por ejemplo 5 cambios de nick, el bot hiciera los cambios de modos y pusiera en primer lugar NWj 3:1 y los 1800 segundos los retirara los modos puesto.

Pero igualmente voy a probar el tuyo, y ya te digo si me funciono.

Desconectado Hanna

  • Miembro Junior
  • **
  • Mensajes: 66
  • Karma: +13/-4
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #3 en: Abril 18, 2020, 12:33:29 pm »
Buenas de nuevo.

A ver si me explico mejor en este.

Lo que quiero si se cambian varios nick de golpe o sea 4 o 5 en menos de 5segundos active automaticamente el NWj 3:1 y pasado 30minutos desactive esos modos que se habían puesto.

¿Mejor ahora?

Un saludo

Y muchas gracias.

Desconectado Quetzalcoatl

  • Miembro de pleno derecho
  • ***
  • Mensajes: 160
  • Karma: +226/-2
  • HipercomputoHipermegared
    • elchatirc
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #4 en: Abril 18, 2020, 06:39:07 pm »
Eso te serviría como pides, solo cambiarías la sección de los temporizadores que están como

  .timer-INICIO-FloodCambio 1 5 .mode #sevilla +NWj 3:1 | .timer-FIN-FloodCambio 1 60 mode #Sevilla -NWj

si el modo quieres que se aplique sin esperar los 5 segundos solo quitas el primer timer y en el que que quita los modos entonces cambiarías el 60(1 minuto) por el tiempo que requieres, en tal caso dices que sean 30 min seria poner $calc(60*30)  y quedaría algo como:
Código: [Seleccionar]
.mode #sevilla +NWj 3:1 | .timer-FIN-FloodCambio 1 $calc(60*30) mode #Sevilla -NWj
Saludos

Desconectado Hanna

  • Miembro Junior
  • **
  • Mensajes: 66
  • Karma: +13/-4
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #5 en: Abril 19, 2020, 11:15:28 am »
Hola.

Perdona por ser tan novata en esto.

Entonces si pongo este código:

Código: [Seleccionar]
;==== Inicio del comprobador de cambios de nicks rapidos.
on 1:nick: {
  if ($nick !ison #sevilla) { return }
  if (%Nick_Flood-cambio. [ $+ [ $nick ] ] == $null) { set -u4 %Nick_Flood-cambio. [ $+ [ $nick ] ] 0 }
  inc %Nick_Flood-cambio. [ $+ [ $nick ] ]
  if ((%Nick_Flood-cambio. [ $+ [ $nick ] ] == 3) && (%Nick_Flood-cambio.#sevilla != 1)) {
     set -u60 %Nick_Flood-cambio.#sevilla 1
    .mode #sevilla +NWj 3:1 | .timer-FIN-FloodCambio 1 $calc(60*30) mode #Sevilla -NWj
  }
}
;==== EOF

y pasa esto:

dswdedfe ahora es eerfrf
efgrgter ahora es efregertf
sdefrf ahora es kkgtgvd
efrgbhg ahora es owdoejf
yhytbyt ahora es qwswew

¿Funcionará?

A lo que me refiero, que no tiene que ser la misma persona, si no 5 cambios de nick seguidos da igual de quien sea.

Un saludo.

Desconectado Hanna

  • Miembro Junior
  • **
  • Mensajes: 66
  • Karma: +13/-4
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #6 en: Abril 19, 2020, 04:27:44 pm »
Hola he modificado la línea y no hace nada.

16:24 ?                         => ¦ ioni es ahora ee
16:24 ?                         => ¦ ee es ahora ajdf
16:24 ?                         => ¦ ajdf es ahora dfgfgt
16:24 ?                         => ¦ dfgfgt es ahora dfgfgtfgtg
16:24 ?                         => ¦ QuieroChat-2144 es ahora hombrchatea
16:24 ?                         => ¦ dfgfgtfgtg es ahora dfgfgtfgtgtyhyrhjj

Y no ha hecho nada.

Código: [Seleccionar]
;==== Inicio del comprobador de cambios de nicks rapidos.
on 1:nick: {
  if ($nick !ison #Sevilla) { return }
  if (%Nick_Flood-cambio. [ $+ [ $nick ] ] == $null) { set -u4 %Nick_Flood-cambio. [ $+ [ $nick ] ] 0 }
  inc %Nick_Flood-cambio. [ $+ [ $nick ] ]
  if ((%Nick_Flood-cambio. [ $+ [ $nick ] ] == 3) && (%Nick_Flood-cambio.#Sevilla != 1)) {
     set -u10 %Nick_Flood-cambio.#Sevilla 1
    .mode #Sevilla +NWj 3:1 | .timer-FIN-FloodCambio 1 $calc(10*30) mode #Sevilla -NWj
  }
}
;==== EOF

Así lo tengo puesto.

Desconectado Quetzalcoatl

  • Miembro de pleno derecho
  • ***
  • Mensajes: 160
  • Karma: +226/-2
  • HipercomputoHipermegared
    • elchatirc
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #7 en: Abril 19, 2020, 06:39:01 pm »
Tienes razón el problema es que me base en el código que pusiste, por que usas el parámetro de $nick, pero si este es rotativo, por ende, esta generando nuevas variables que nunca cumplirán esta condición, lo ideal es meterlo por medio de la $address. La cual es identd@mask, siendo ambos parámetros que no se pueden cambiar a menos que se desconecten para la identd.
Código: [Seleccionar]
;==== Inicio del comprobador de cambios de nicks rápidos.
on 1:nick: {
  if ($nick !ison #Sevilla) { return }
  if (%Nick_Flood-cambio. [ $+ [ $address ] ] == $null) { set -u4 %Nick_Flood-cambio. [ $+ [ $address ] ] 0 }
  inc %Nick_Flood-cambio. [ $+ [ $address ] ]
  if ((%Nick_Flood-cambio. [ $+ [ $address ] ] == 3) && (%Nick_Flood-cambio.#Sevilla != 1)) {
     set -u10 %Nick_Flood-cambio.#Sevilla 1
    .mode #Sevilla +NWj 3:1 | .timer-FIN-FloodCambio 1 $calc(10*30) mode #Sevilla -NWj
  }
}
;==== EOF

Desconectado Hanna

  • Miembro Junior
  • **
  • Mensajes: 66
  • Karma: +13/-4
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #8 en: Abril 19, 2020, 08:32:52 pm »
Hola.

Para cumplir los requisitos, debe haber 3 cambios de nicks en 10 segundos o menos, ¿No?

Un saludo.

Desconectado Quetzalcoatl

  • Miembro de pleno derecho
  • ***
  • Mensajes: 160
  • Karma: +226/-2
  • HipercomputoHipermegared
    • elchatirc
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #9 en: Abril 19, 2020, 08:49:16 pm »
en tu codigo original lo tienes para 4s
set -u4 %Nick_Flood [ $+ [ $nick ] ] 0

por eso lo deje con 4 igual
if (%Nick_Flood-cambio. [ $+ [ $address ] ] == $null) { set -u4 %Nick_Flood-cambio. [ $+ [ $address ] ] 0 }

los cambios dependen del tres de la la comparación
  if ((%Nick_Flood-cambio. [ $+ [ $address ] ] == 3) && (%Nick_Flood-cambio.#Sevilla != 1)) {

y si es correcto son tres cambios, debido a la primera condición que revisa si existe de lo contrario crea la variable con cero y despues la incrementa independiente si existe o no hasta llegar a que sean 3, y la variable desaparecerá por el 4 que se coloco al crear la variable de revision.

Desconectado Hanna

  • Miembro Junior
  • **
  • Mensajes: 66
  • Karma: +13/-4
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #10 en: Abril 19, 2020, 08:54:35 pm »
Hola.

Entonces si no lo he entendido mal...

Si a los 4 segundos hubo 3 cambios nicks (de cualquier usuario) se activan esos modos?

¿es eso? ¿o lo entendido mal?

Desconectado Quetzalcoatl

  • Miembro de pleno derecho
  • ***
  • Mensajes: 160
  • Karma: +226/-2
  • HipercomputoHipermegared
    • elchatirc
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #11 en: Abril 19, 2020, 09:14:38 pm »
si un usuario(cualquiera) hace un cambio consecutivo de su nick(minimo 3veces), en menos de 4 segundos, Se activara.

Desconectado Hanna

  • Miembro Junior
  • **
  • Mensajes: 66
  • Karma: +13/-4
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #12 en: Abril 20, 2020, 03:52:13 am »
Hola Quetzalcoatl.

Entonces me he explicado mal, lo que queria es que si hubiera 5 cambios de nick en 5seg o menos se pusieran
los modos del canal, los nicks no tienen que ser de una persona, vale 5 nick de 5 usuarios distinto.

Hanna ahora es Ana
Jose es ahora Josema
Diego es ahora DiegoBcn
PedroBcn es ahora Darwin
hult es ahora Raulillo

En ese momento el bot pone los modos de arrba, o sea +NWj 3:1 y a los 1800 segundo se quiten los modos.

¿Me explique mejor ahora?

Un saludo y muchas gracias

Desconectado Quetzalcoatl

  • Miembro de pleno derecho
  • ***
  • Mensajes: 160
  • Karma: +226/-2
  • HipercomputoHipermegared
    • elchatirc
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #13 en: Abril 20, 2020, 06:05:40 am »
si te fijas no hay mucha diferencia a tu primer código, excepto que no se usa una variable dinámica, la aplicación de modos, la comprobación si los cambios son en el canal de sevilla y si tu eres op.
Código: [Seleccionar]
;==== Inicio del comprobador de cambios de nicks rápidos.
on 1:nick: {
  if (($nick !ison #Sevilla) || ($me !isop #sevilla)) { return }
  if (%Nick_Flood-cambio == $null) { set -u5 %Nick_Flood-cambio 0 }
  inc %Nick_Flood-cambio
  if (%Nick_Flood-cambio == 5) {
  .mode #Sevilla +NWj 3:1 | .timer-FIN-FloodCambio 1 1800 mode #Sevilla -NWj
  }
}
;==== EOF
cuando sean seguidos 5 cambios de nicks(independiente de si es el mismo usuario u otro), en un lapso de 5 segundos, se aplicaran los modos y el temporizador.

Con esto concluyo mi participación en este tema.

Saludos

Desconectado Hanna

  • Miembro Junior
  • **
  • Mensajes: 66
  • Karma: +13/-4
Re:Poner modos automaticos cuando se cambian varios nick de forma seguida.
« Respuesta #14 en: Abril 20, 2020, 03:43:06 pm »
Hola.

Muchas gracias por tu ayuda!!!!

PD: Te he dado voto porque te lo has merecido!