buenas de nuevo a ver si alguna alma caritativa ayuda a resolver lo que me gustaría hacer.
me gustaría hacer: como agregar la conexión directa para que se conecte a una znc -m ip puerto admin/N.red:pass ya que solo pide nombre de los server redes puertos a ver si se le puede agregar admin/N.red:pass y se conecte directamente
gracias nuevamente
::::::::::::::::::::::::::::
:::::: Coded By eNkIL ::::::
::::::::::::::::::::::::::::
::: Cambiale si sabes =) :::
::::::::::::::::::::::::::::
;Conexión
menu menubar,channel,status {
Connect:conn
-
}
alias conn {
if ($dialog(connect) == $null) { dialog -m connect connect }
else { .echo -a -Dialogo de Conexion Ejecutandose.. }
}
alias -l conn.load.net {
if ($exists(servers) == $false) { mkdir servers | write -c servers\delete.txt DELETE }
did -r $dname 101 | %g = 1
while ($findfile(servers\,*.txt,%g)) {
did -a $dname 101 $remove($nopath($findfile(servers\,*.txt,%g)),.txt)
inc %g
}
unset %g
}
alias -l conn.load.serv {
did -r $dname 201 | %f = servers\ $+ $did($dname,101,$did($dname,101).sel).text | %f = %f $+ .txt | %g = 2
while ($read(%f,%g)) {
did -a $dname 201 $gettok($read(%f,%g),1,58)
inc %g
}
}
alias -l conn.rand.ident {
return $rand(a,z) $+ $rand(a,z) $+ $rand(a,z) $+ $rand(0,9) $+ $rand(0,9) $+ $rand(0,9) $+ $rand(0,9)
}
alias -l conn.info.serv {
%kk = $1 $+ *
%l = $read(servers\ $+ $did($dname,101,$did($dname,101).sel).text $+ .txt,w,%kk)
did -a $dname 602 $gettok(%l,2,58)
did -a $dname 604 $gettok(%l,4,58)
did -a $dname 505 $mid($gettok(%l,3,58),1,4)
did -a $dname 505 $mid($gettok(%l,3,58),6,4)
did -a $dname 505 $mid($gettok(%l,3,58),11,4)
did -a $dname 505 $mid($gettok(%l,3,58),16,4)
did -a $dname 505 $mid($gettok(%l,3,58),21,4)
did -a $dname 505 $mid($gettok(%l,3,58),26,6)
did -a $dname 505 $mid($gettok(%l,3,58),31,4)
did -c $dname 505 1 | unset %l %kk
}
alias -l conn.add.net {
set %addred $$?="¿Nombre de red? Ej: Undernet"
write servers\ $+ %addred $+ .txt < $+ %addred $+ >
conn.load.net | conn.load.serv
}
alias -l conn.add.serv {
if (!$did($dname,101,$did($dname,101).sel).text) { echo -at Seleccione la red a la que le gustaría agregar el servidor. | halt }
set %addserv1 $$?="Agregar servidor desde: $did($dname,101,$did($dname,101).sel).text $+ . Ej: irc.undernet.org"
set %addserv2 $$?="¿Nombre del servidor? Ej: Undernet"
set %addserv3 $$?="¿Puertos?. Ej: 6667,6668"
set %addserv4 $$?="País del servidor. Ej: EE. UU., CANADÁ."
write servers\ $+ $did($dname,101,$did($dname,101).sel).text $+ .txt %addserv2 $+ : $+ %addserv1 $+ : $+ %addserv3 $+ : $+ %addserv4
unset %addserv1 %addserv2 %addserv3 %addserv4
conn.load.serv
}
alias -l conn.rem.net {
if (!$did($dname,101,$did($dname,101).sel).text) { echo -at Seleccione la red que desea eliminar. | halt }
set %n $$?!="¿Está seguro de que desea eliminar $did($dname,101,$did($dname,101).sel).text de la lista?"
if (%n) { .remove servers\ $+ $did($dname,101,$did($dname,101).sel).text $+ .txt | conn.load.net | conn.load.serv }
unset %n
}
alias -l conn.rem.serv {
if (!$did($dname,201,$did($dname,201).sel).text) { echo -at Seleccione el servidor que desea eliminar de la lista. | halt }
set %n $$?!="¿Estas seguro que quieres eliminar $did($dname,201,$did($dname,201).sel).texto de la lista?"
if (%n) {
%l = $read(servers\ $+ $did($dname,101,$did($dname,101).sel).text $+ .txt,w,$did($dname,201,$did($dname,201).sel).text $+ *)
write -dl $+ $readn servers\ $+ $did($dname,101,$did($dname,101).sel).text $+ .txt
conn.load.serv
}
unset %n %l
}
alias -l conn.save.con {
.server $did($dname,602).text $did($dname,505).text
set %conn.auto.serv $did($dname,602).text $did($dname,505).text
set %conn.modes.me $did($dname,307)
var %nick = $did($dname,301)
var %anick = $did($dname,302)
if (%nick && %nick != $me) .nick %nick
elseif (!%nick) .nick Nick1
if (%anick) .anick %anick
else .anick Nick2
set %conn.ident.sel $did($dname,303).state
var %ident_a = $did($dname,305)
var %ident_b = $did($dname,306)
if (%conn.ident.sel) { .identd on $iif(%ident_a,$ifmatch,None) }
else { .identd on $iif(%ident_b,$ifmatch,None) }
set %conn.ident $iif(%ident_a,$ifmatch,None)
echo -a ok
}
dialog connect {
title "Centro de conexión"
size -1 -1 410 170
option dbu
;=====Red=====
box "Red", 100, 2 2 75 122
list 101, 4 10 71 100, size vsbar
button "Agregra", 102, 5 110 28 12
button "Borrar", 103, 40 110 28 12
;=====Servidores=====
box "Servidores", 200, 80 2 75 122
list 201, 82 10 71 100, size vsbar
button "Agregar", 202, 83 110 28 12
button "Borrar", 203, 115 110 28 12
;=====Nick=====
box "", 300, 208 2 176 44
text "Nick:", 2, 210 11 25 8, center
edit "", 301, 236 10 48 10, autohs
text "Otro nick", 4, 210 23 25 8, center
edit "", 302, 236 22 48 10, autohs
radio "Ident:", 303, 290 10 38 10
radio "Al Azar:", 304, 290 22 44 10
edit "", 305, 334 10 48 10, autohs
edit "", 306, 334 22 48 10, read autohs
text "Modos de conexión:", 10, 275 35 58 8,
edit "", 307, 334 34 48 10, autohs
;=====Conectar=====
box "", 400, 208 46 176 22
button "Disconectar", 401, 210 53 37 12
button "Conectar", 402, 278 53 37 12
button "Cerrar", 403, 345 53 37 12, ok cancel
;=====Puertos=====
box "", 500, 160 68 81 56
check "Conectar al Inicio", 501, 162 73 50 10
check "Abrir al Inicio", 502, 162 90 50 10
text "Puertos:", 504, 162 111 20 8
combo 505, 183 109 50 50, drop, size
;=====Servidor=====
box "", 600, 250 68 150 56
text "Servidor:", 601, 253 81 21 8
edit "", 602, 275 80 120 10, read, center
text "Pass:", 603, 253 104 25 8
edit "", 604, 275 103 120 10, read, center
}
on *:dialog:connect:*:*: {
if ($devent = init) {
conn.load.net
if ($server != $null) { did -a $dname 602 $server | did -a $dname 600 Connected }
if (%conn.auto.start) { did -c $dname 501 }
if (%conn.show.start) { did -c $dname 502 }
if (%conn.ident.sel) { did -c $dname 303 } | else { did -c $dname 304 }
did -a $dname 301 $me
did -a $dname 302 $anick
did -a $dname 305 %conn.ident
did -a $dname 306 $conn.rand.ident
did -a $dname 307 %conn.modes.me
}
if ($devent = sclick) {
if ($did = 101) { did -r $dname 201 | did -z $dname 101 | did -z $dname 201 | conn.load.serv $did($dname,101,$did($dname,101).sel).text }
if ($did = 102) { conn.add.net }
if ($did = 103) { conn.rem.net }
if ($did = 201) { did -z $dname 101 | did -z $dname 201 | did -r $dname 505 | did -r $dname 602 | did -r $dname 604 | conn.info.serv $did($dname,201,$did($dname,201).sel).text }
if ($did = 202) { conn.add.serv }
if ($did = 203) { conn.rem.serv }
if ($did = 304) { did -r $dname 306 | did -a $dname 306 $conn.rand.ident }
if ($did = 401) { disconnect }
if ($did = 402) { conn.save.con }
if ($did = 501) { set %conn.auto.start $did($dname,501).state }
if ($did = 502) { set %conn.show.start $did($dname,502).state }
}
if ($devent = dclick) {
if ($did = 201) { conn.save.con }
}
}
on *:start: {
if (%conn.show.start) { conn }
if (%conn.auto.start) {
.server %conn.auto.serv
}
}
on *:connect:{
if $dialog(connect) { did -ra connect 602 $server | did -a connect 600 Connected }
.mode $me %conn.modes.me
}
