Autor Tema: Tengo un remote que es anti repeticiones con advertencia  (Leído 7804 veces)

0 Usuarios y 1 Visitante están viendo este tema.

Desconectado Dino

  • Miembro Junior
  • **
  • Mensajes: 50
  • Karma: +0/-45
Tengo un remote que es anti repeticiones con advertencia
« en: Enero 21, 2020, 04:57:33 am »
Tengo un remote que es anti repeticiones con advertencia y a la tercera da bankick.. pero no funciona me pueden corregir por favor

on @*:text:*:#: {
  if ($nick isreg #) { floodpesados }
}
alias floodpesados {
  inc -u2 $+(%,flood,.,$chan,.,txt,.,$nick)
  if $($+(%,flood,.,$chan,.,txt,.,$nick),2) >= 2 {
    inc -u800 $+(%,floodd,.,$chan,.,$nick) 
    if ($($+(%,floodd,.,$chan,.,$nick),2) = 1 ) { msg $chan 4AVISO12 $nick 1Porfavor no 44repita.11 Esta practica floodea el canal.  }
    if ($($+(%,floodd,.,$chan,.,$nick),2) = 2 ) { msg $chan $nick no repitas ultimo aviso }
    if ($($+(%,floodd,.,$chan,.,$nick),2) = 3 ) { Ban u120 $addres($nick,2) | kick $chan $nick Expulsado por repeticiones. }
  }
}

Desconectado rayco

  • Miembro Junior
  • **
  • Mensajes: 82
  • Karma: +1/-73
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #1 en: Enero 21, 2020, 02:25:03 pm »
Hola.

Cambia está línea:

Código: [Seleccionar]
if ($($+(%,floodd,.,$chan,.,$nick),2) = 3 ) { Ban u120 $addres($nick,2) | kick $chan $nick Expulsado por repeticiones. }
Por está línea:

Código: [Seleccionar]
if ($($+(%,floodd,.,$chan,.,$nick),2) = 3 ) { ban -u120 $chan $addres($nick,2) | kick $chan $nick Expulsado por repeticiones. }

Un saludo.

Desconectado Cadaver

  • Miembro de pleno derecho
  • ***
  • Mensajes: 124
  • Karma: +152/-3
  • Sexo: Masculino
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #2 en: Enero 21, 2020, 04:53:04 pm »
No va a funcionar porque estas llamando un alias sin argumentos, puedes llamar el alias como { floodpesados $nick $chan } y cambias en el alias $nick por $1 y $chan por $2 ademas que tienes errores en la llamada de variables con $identificadores e incluso las variables mal escritas, también puedes eliminar el alias:

Código: [Seleccionar]
on *:TEXT:*:#: {
  if ($nick isreg $chan) && ($me isop $chan) {
    inc -u500 $+(%,flood,.,$chan,.,txt,.,$nick)
    if (%flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ] == 2) { msg $chan AVISO 1 }
    if (%flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ] == 3) { msg $chan AVISO 2 }
    if (%flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ] == 4) { ban -u120 $chan $address($nick,2) | kick $chan $nick Razon del KICK }
  }
}

Asi debe quedar funcional solo es cuestión de que modifiques el inc -u a tus necesidades ...
« última modificación: Enero 21, 2020, 05:18:26 pm por Cadaver »

Desconectado Dino

  • Miembro Junior
  • **
  • Mensajes: 50
  • Karma: +0/-45
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #3 en: Enero 22, 2020, 02:16:29 am »
Gracias amigos voy a probar  :)

Desconectado Dino

  • Miembro Junior
  • **
  • Mensajes: 50
  • Karma: +0/-45
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #4 en: Enero 22, 2020, 02:41:32 am »
No funciono ninguna sugerencia hice pruebas de ambas y no funciona

Desconectado MiLeNiUm

  • Novato
  • *
  • Mensajes: 9
  • Karma: +0/-16
  • Sexo: Masculino
  • CaEr EsTa PeRmItIdO lEvAnTaRsE eS oBLiGaToRiO
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #5 en: Enero 22, 2020, 03:55:02 am »
Buenas, yo uso este y funciona muy bien, espero que te sirva como a mi, saludos.  :)
Código: [Seleccionar]
#Repite on
on *:TEXT:*:%pral: {
  if ($ulevel >= 60) || ($ulevel >= 100) { halt }
  if ($ulevel < 100) {
    if ($nick !isop $chan) && ($nick isvo $chan) && ($me isop $chan) { return }
    if (%NickRepite. [ $+ [ $nick ] ] == $null) { set -u300 %NickRepite. [ $+ [ $nick ] ] 0 $1- }
    else if (%NickRepite. [ $+ [ $nick ] ] != $null) {
      if ($gettok(%NickRepite. [ $+ [ $nick ] ],1,32) == 0) && ($gettok(%NickRepite. [ $+ [ $nick ] ],2-,32) == $1-) {
        PRIVmsg $chan 2 $+ $nick $+  12--> 2Por favor, 4No repita. 2Con una vez ya le leemos. 12(1er Aviso)
        PRIVmsg %ops 2Avisando a 1 $+ $nick $+  2de que no repita una frase o texto. 12[1]
        set -u1200 %NickRepite. [ $+ [ $nick ] ] $calc($gettok(%NickRepite. [ $+ [ $nick ] ],1,32) + 1) $gettok(%NickRepite. [ $+ [ $nick ] ],2-,32)
        return
      }
      else if ($gettok(%NickRepite. [ $+ [ $nick ] ],1,32) == 1) && ($gettok(%NickRepite. [ $+ [ $nick ] ],2-,32) == $1-) {
        msg $chan 2 $+ $nick $+  12--> 2Por favor, 4No repita. 2Con una vez ya le leemos. 12(2ndo Aviso)
        PRIVmsg %ops 2Avisando a 1 $+ $nick $+  2de que no repita una frase o texto. 12[2]   
        set -u1200 %NickRepite. [ $+ [ $nick ] ] $calc($gettok(%NickRepite. [ $+ [ $nick ] ],1,32) + 1) $gettok(%NickRepite. [ $+ [ $nick ] ],2-,32)
        return
      }   
      else if ($gettok(%NickRepite. [ $+ [ $nick ] ],1,32) == 2) && ($gettok(%NickRepite. [ $+ [ $nick ] ],2-,32) == $1-) {
        PRIVmsg $nick 4Se le Advirtío De que no Repitiera. Esta práctica molesta a los demas usuarios del canal, gracias y hasta pronto.
        ban -u1800 $chan $address($nick,2)
        kick $chan $nick Repetir una frase o una idea es molesto para el canal, con una vez ya le leemos.
        unset %NickRepite. [ $+ [ $nick ] ]
      }
      else {
        set -u300 %NickRepite. [ $+ [ $nick ] ] 0 $1-
      }
    }
  }
}
#Repite end

Desconectado Cadaver

  • Miembro de pleno derecho
  • ***
  • Mensajes: 124
  • Karma: +152/-3
  • Sexo: Masculino
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #6 en: Enero 22, 2020, 06:03:07 pm »
Si funciona, tienes que revisar que no tengas varios eventos on TEXT en el mismo archivo o incluso si hay muchos eventos del mismo tipo en diferentes archivos suele ocasionar problemas:

Citar
 10:58:28  (Hugo): .
 10:58:30  (Hugo): .
 10:58:30  (@Cadaver): AVISO 1
 10:58:33  (Hugo): .
 10:58:33  (@Cadaver): AVISO 2
 10:58:34  (Hugo): .
 10:58:35  ••• mode (@Cadaver) sets: '+b *!*@Hugo.Sa.nchez.MX'
 10:58:35  ••• kick (Hugo) (Futbol@Hugo.Sa.nchez.MX) [#ElChatIRC] by (@Cadaver) (Razon del KICK)

Vuelvo a copiar el código solo con otra modificación:

Código: [Seleccionar]
on *:TEXT:*:#: {
  if ($nick isreg $chan) && ($me isop $chan) {
    inc -u500 $+(%,flood.,$chan,.txt.,$nick)
    if (%flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ] == 2) { msg $chan AVISO 1 }
    if (%flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ] == 3) { msg $chan AVISO 2 }
    if (%flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ] == 4) { ban -u120 $chan $address($nick,2) | kick $chan $nick Razon del KICK | unset $+(%,flood.,$chan,.txt.,$nick) }
  }
}

Desconectado Dino

  • Miembro Junior
  • **
  • Mensajes: 50
  • Karma: +0/-45
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #7 en: Enero 24, 2020, 07:20:49 am »
gracias a los dos por la ayuda MiLeNiUm2 y cadaver
el codigo de cadaver funciona pero tiene un fallo que cuando cambio de frase en la tercera vez igual me banea deberia parar el ban pero no sigue la secuencia.
en relacion del codigo de MiLeNiUm2 funciona de maravilla lo prove y si funciona a la perfeccion gracias a los dos por su tiempo.

Desconectado Dino

  • Miembro Junior
  • **
  • Mensajes: 50
  • Karma: +0/-45
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #8 en: Febrero 01, 2020, 05:43:56 am »
me sucedio el mismo detalle funciona bien pero cuando repito la misma frase en otro canal ya me lanza la segunda advertencia y no empieza desde cero..
Código: [Seleccionar]
#Repite on
on *:TEXT:*:%pral: {
  if ($ulevel >= 60) || ($ulevel >= 100) { halt }
  if ($ulevel < 100) {
    if ($nick !isop $chan) && ($nick isvo $chan) && ($me isop $chan) { return }
    if (%NickRepite. [ $+ [ $nick ] ] == $null) { set -u300 %NickRepite. [ $+ [ $nick ] ] 0 $1- }
    else if (%NickRepite. [ $+ [ $nick ] ] != $null) {
      if ($gettok(%NickRepite. [ $+ [ $nick ] ],1,32) == 0) && ($gettok(%NickRepite. [ $+ [ $nick ] ],2-,32) == $1-) {
        PRIVmsg $chan 2 $+ $nick $+  12--> 2Por favor, 4No repita. 2Con una vez ya le leemos. 12(1er Aviso)
        PRIVmsg %ops 2Avisando a 1 $+ $nick $+  2de que no repita una frase o texto. 12[1]
        set -u1200 %NickRepite. [ $+ [ $nick ] ] $calc($gettok(%NickRepite. [ $+ [ $nick ] ],1,32) + 1) $gettok(%NickRepite. [ $+ [ $nick ] ],2-,32)
        return
      }
      else if ($gettok(%NickRepite. [ $+ [ $nick ] ],1,32) == 1) && ($gettok(%NickRepite. [ $+ [ $nick ] ],2-,32) == $1-) {
        msg $chan 2 $+ $nick $+  12--> 2Por favor, 4No repita. 2Con una vez ya le leemos. 12(2ndo Aviso)
        PRIVmsg %ops 2Avisando a 1 $+ $nick $+  2de que no repita una frase o texto. 12[2]   
        set -u1200 %NickRepite. [ $+ [ $nick ] ] $calc($gettok(%NickRepite. [ $+ [ $nick ] ],1,32) + 1) $gettok(%NickRepite. [ $+ [ $nick ] ],2-,32)
        return
      }   
      else if ($gettok(%NickRepite. [ $+ [ $nick ] ],1,32) == 2) && ($gettok(%NickRepite. [ $+ [ $nick ] ],2-,32) == $1-) {
        PRIVmsg $nick 4Se le Advirtío De que no Repitiera. Esta práctica molesta a los demas usuarios del canal, gracias y hasta pronto.
        ban -u1800 $chan $address($nick,2)
        kick $chan $nick Repetir una frase o una idea es molesto para el canal, con una vez ya le leemos.
        unset %NickRepite. [ $+ [ $nick ] ]
      }
      else {
        set -u300 %NickRepite. [ $+ [ $nick ] ] 0 $1-
      }
    }
  }
}
#Repite end
alguien porfa que me ayude a agregar la variante canal para que asi las advertencias sean independientes una y de otra
ejemplo si en #lumm repito una frase y la misma frase la repito en #caps me lanza directo a la segunda advertencia y en #caps
deberia empezar de nuevo... gracias

Desconectado Quetzalcoatl

  • Miembro de pleno derecho
  • ***
  • Mensajes: 201
  • Karma: +241/-2
  • HipercomputoHipermegared
    • elchatirc
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #9 en: Febrero 01, 2020, 05:55:41 am »
usa la misma variante que usaste en el codigo de antimayusculas
%_cuenta. [ $+ [ $+($nick,.,$chan) ] ]
solo modificas la creacion de la variable
en este caso originalmente la tienes como :
Citar
%NickRepite. [ $+ [ $nick ] ]
te quedaria como :
Citar
%NickRepite. [ $+ [ $+($nick,.,$chan) ] ]
por lo tanto quedara algo como............
Código: [Seleccionar]
#Repite on
on *:TEXT:*:%pral: {
  if ($ulevel >= 60) || ($ulevel >= 100) { halt }
  if ($ulevel < 100) {
    if ($nick !isop $chan) && ($nick isvo $chan) && ($me isop $chan) { return }
    if (%NickRepite. [ $+ [ $+($nick,.,$chan) ] ] == $null) { set -u300 %NickRepite. [ $+ [ $+($nick,.,$chan) ] ] 0 $1- }
    else if (%NickRepite. [ $+ [ $+($nick,.,$chan) ] ] != $null) {
      if ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) == 0) && ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32) == $1-) {
        PRIVmsg $chan 2 $+ $nick $+  12--> 2Por favor, 4No repita. 2Con una vez ya le leemos. 12(1er Aviso)
        PRIVmsg %ops 2Avisando a 1 $+ $nick $+  2de que no repita una frase o texto. 12[1]
        set -u1200 %NickRepite. [ $+ [ $+($nick,.,$chan) ] ] $calc($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) + 1) $gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32)
        return
      }
      else if ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) == 1) && ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32) == $1-) {
        msg $chan 2 $+ $nick $+  12--> 2Por favor, 4No repita. 2Con una vez ya le leemos. 12(2ndo Aviso)
        PRIVmsg %ops 2Avisando a 1 $+ $nick $+  2de que no repita una frase o texto. 12[2]   
        set -u1200 %NickRepite. [ $+ [ $+($nick,.,$chan) ] ] $calc($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) + 1) $gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32)
        return
      }   
      else if ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) == 2) && ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32) == $1-) {
        PRIVmsg $nick 4Se le Advirtío De que no Repitiera. Esta práctica molesta a los demas usuarios del canal, gracias y hasta pronto.
        ban -u1800 $chan $address($nick,2)
        kick $chan $nick Repetir una frase o una idea es molesto para el canal, con una vez ya le leemos.
        unset %NickRepite. [ $+ [ $+($nick,.,$chan) ] ]
      }
      else {
        set -u300 %NickRepite. [ $+ [ $+($nick,.,$chan) ] ] 0 $1-
      }
    }
  }
}
#Repite end

No he probado el código, pero intenta haber si es lo que requieres.

Saludos

Desconectado Dino

  • Miembro Junior
  • **
  • Mensajes: 50
  • Karma: +0/-45
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #10 en: Febrero 01, 2020, 06:28:56 am »
funciono de maravilla
pero encontre otro detalle que no funciona

Desconectado Dino

  • Miembro Junior
  • **
  • Mensajes: 50
  • Karma: +0/-45
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #11 en: Febrero 01, 2020, 06:33:13 am »
<master> heyyyy
<master> heyyyy
<@JetLee> master ==>> Por favor, No repitas Con una vez ya le leemos. (1er Aviso) <<==
<master> heyyyy
<@JetLee> master ==>> Calmate, trata de escribir todo en una sola linea por favor. (2do Aviso) <<==
<master> yaaa
<master> heyyyyy
<master> heyyyyy
<@JetLee> master ==>> Por favor, No repitas Con una vez ya le leemos. (1er Aviso) <<==

si digo la frase dos veces me advierte pero si meto una frase que no esta repetida y luego vuelvo a repetir la anterior frase no castiga
y el conteo empieza desde cero...
el detalle es que al repetir en la tercera vez pero intercalado con una frase la secuencia deberia de continuar y aplicar el castigo cosa que no lo hace.. se puede solucionar ese detalle??

Desconectado Quetzalcoatl

  • Miembro de pleno derecho
  • ***
  • Mensajes: 201
  • Karma: +241/-2
  • HipercomputoHipermegared
    • elchatirc
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #12 en: Febrero 02, 2020, 09:45:21 pm »
no es propiamente un detalle que no funciona, más bien así esta hecho el código que funcione, cuando se repite una frase seguida y por ello reinicia los valores en las advertencia sin son diferente los textos de la linea previa a la ultima.

funciono de maravilla
pero encontre otro detalle que no funciona.

Lo que se puede hacer es crear una variable independiente que cuente si ha sido advertido por las repeticiones, y que esta variable sea temporal, y mantenga este valor por 5 min, después de eso desaparecerá.

Código: [Seleccionar]
#Repite on
on *:TEXT:*:%pral: {
  if ($ulevel >= 60) || ($ulevel >= 100) { halt }
  if ($ulevel < 100) {
    if ($nick !isop $chan) && ($nick isvo $chan) && ($me isop $chan) { return }
    if (%NickRepite. [ $+ [ $+($nick,.,$chan) ] ] == $null) { set -u300 %NickRepite. [ $+ [ $+($nick,.,$chan) ] ] 0 $1- }
    else if (%NickRepite. [ $+ [ $+($nick,.,$chan) ] ] != $null) { var %advertido = %NickRepite.Advertido. [ $+ [ $+($nick,.,$chan) ] ]
    ;----Si el usuario no ha sido advertido se crea una variable individual de lo contrario incrementa y va una advertencia definida.
    if (!%advertido) { set -u300 %NickRepite.Advertido. [ $+ [ $+($nick,.,$chan) ] ] 1 }
else { set -u300 %NickRepite.Advertido. [ $+ [ $+($nick,.,$chan) ] ] $calc(%advertido +1) | goto $calc(%advertido +1) }
    ;---- fin de la  manipulacin de la variable de advertencia
      if ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) == 0) && ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32) == $1-) {
        PRIVmsg $chan 2 $+ $nick $+  12--> 2Por favor, 4No repita. 2Con una vez ya le leemos. 12(1er Aviso)
        PRIVmsg %ops 2Avisando a 1 $+ $nick $+  2de que no repita una frase o texto. 12[1]
        set -u1200 %NickRepite. [ $+ [ $+($nick,.,$chan) ] ] $calc($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) + 1) $gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32)
        return
      }
      else if ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) == 1) && ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32) == $1-) {
        :2 | msg $chan 2 $+ $nick $+  12--> 2Por favor, 4No repita. 2Con una vez ya le leemos. 12(2ndo Aviso)
        PRIVmsg %ops 2Avisando a 1 $+ $nick $+  2de que no repita una frase o texto. 12[2]   
        set -u1200 %NickRepite. [ $+ [ $+($nick,.,$chan) ] ] $calc($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) + 1) $gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32)
        return
      }
      else if ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) == 2) && ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32) == $1-) {
       :3 | PRIVmsg $nick 4Se le Advirtío De que no Repitiera. Esta práctica molesta a los demas usuarios del canal, gracias y hasta pronto.
        ban -u1800 $chan $address($nick,2)
        kick $chan $nick Repetir una frase o una idea es molesto para el canal, con una vez ya le leemos.
        unset %NickRepite. [ $+ [ $+($nick,.,$chan) ] ]
      }
      else {
        set -u300 %NickRepite. [ $+ [ $+($nick,.,$chan) ] ] 0 $1-
      }
    }
  }
}
#Repite end

Solo se agregaron dos lineas de código y otras dos de anotaciones, no he probado el código, pero en teoría te debería funcionar

Saludos.

Desconectado MiLeNiUm

  • Novato
  • *
  • Mensajes: 9
  • Karma: +0/-16
  • Sexo: Masculino
  • CaEr EsTa PeRmItIdO lEvAnTaRsE eS oBLiGaToRiO
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #13 en: Febrero 03, 2020, 03:01:20 am »
el codigo que puse lo ajuste a una sola sala, de ahi la variable %pral y los level es para que "ignore" a los usarios que de nivel tenga 60 o mas o 100, quien tenga menos de ese nivel (en el bot), seria expulsado por repeticiones.

Desconectado Dino

  • Miembro Junior
  • **
  • Mensajes: 50
  • Karma: +0/-45
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #14 en: Febrero 06, 2020, 08:26:42 pm »
use el que modifico Quetzalcoatl y dejo de funcioanar no advierte no banea ...   :-\

Desconectado Quetzalcoatl

  • Miembro de pleno derecho
  • ***
  • Mensajes: 201
  • Karma: +241/-2
  • HipercomputoHipermegared
    • elchatirc
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #15 en: Febrero 07, 2020, 01:48:30 am »
dino
prueba con esto, esta corregido lo del goto y otros detalles, cuando algo no funcione por favor dilo de inmediato, no había probado el codigo anterior, pero este lo acabo probar y creo que funciona como lo requieres
Código: [Seleccionar]
#Repite on
on *:TEXT:*:%pral: {
  if (($ulevel >= 60) || ($ulevel >= 100) || ($me == $nick) || ($nick isop $chan)) { halt }
  if ($ulevel < 100) {
    if ($nick !isop $chan) && ($nick isvo $chan) && ($me isop $chan) { return }
    if (%NickRepite. [ $+ [ $+($nick,.,$chan) ] ] == $null) { set -u300 %NickRepite. [ $+ [ $+($nick,.,$chan) ] ] 0 $1- }
    else if (%NickRepite. [ $+ [ $+($nick,.,$chan) ] ] != $null) {
      var %advertido = %NickRepite.Advertido. [ $+ [ $+($nick,.,$chan) ] ]
      ;----Si el usuario no ha sido advertido se crea una variable individual de lo contrario incrementa y va una advertencia definida.
      if (!%advertido) { set -u300 %NickRepite.Advertido. [ $+ [ $+($nick,.,$chan) ] ] 1 }
      ;---- fin de la  manipulacion de la variable de advertencia
      if ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) == 0) && ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32) == $1-) {
        if (%advertido) { set -u300 %NickRepite.Advertido. [ $+ [ $+($nick,.,$chan) ] ] $calc(%advertido +1) | goto $calc(%advertido +1) } | :1
        PRIVmsg $chan 2 $+ $nick $+  12--> 2Por favor, 4No repita. 2Con una vez ya le leemos. 12(1er Aviso)
        PRIVmsg %ops 2Avisando a 1 $+ $nick $+  2de que no repita una frase o texto. 12[1]
        set -u1200 %NickRepite. [ $+ [ $+($nick,.,$chan) ] ] $calc($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) + 1) $gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32)
        return
      }
      else if ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) == 1) && ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32) == $1-) {
        if (%advertido) { set -u300 %NickRepite.Advertido. [ $+ [ $+($nick,.,$chan) ] ] $calc(%advertido +1) | goto $calc(%advertido +1) }
        :2 | msg $chan 2 $+ $nick $+  12--> 2Por favor, 4No repita. 2Con una vez ya le leemos. 12(2ndo Aviso)
        PRIVmsg %ops 2Avisando a 1 $+ $nick $+  2de que no repita una frase o texto. 12[2]
        set -u1200 %NickRepite. [ $+ [ $+($nick,.,$chan) ] ] $calc($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) + 1) $gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32)
        return
      }
      else if ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],1,32) == 2) && ($gettok(%NickRepite. [ $+ [ $+($nick,.,$chan) ] ],2-,32) == $1-) {
        if (%advertido) { set -u300 %NickRepite.Advertido. [ $+ [ $+($nick,.,$chan) ] ] $calc(%advertido +1) | goto $calc(%advertido +1) }
        :3 | PRIVmsg $nick 4Se le Advirtío De que no Repitiera. Esta práctica molesta a los demas usuarios del canal, gracias y hasta pronto.
        ban -u1800 $chan $address($nick,2)
        kick $chan $nick Repetir una frase o una idea es molesto para el canal, con una vez ya le leemos.
        unset %NickRepite. [ $+ [ $+($nick,.,$chan) ] ]
        unset %NickRepite.Advertido. [ $+ [ $+($nick,.,$chan) ] ]
      }
      else { echo -s aqui-----
        set -u300 %NickRepite. [ $+ [ $+($nick,.,$chan) ] ] 0 $1-
      }
    }
  }
}
#Repite end

Desconectado MiLeNiUm

  • Novato
  • *
  • Mensajes: 9
  • Karma: +0/-16
  • Sexo: Masculino
  • CaEr EsTa PeRmItIdO lEvAnTaRsE eS oBLiGaToRiO
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #16 en: Febrero 07, 2020, 02:35:31 am »
Hola, lo acabo de probar yo tambien y ahora si funciona, Saludos.

Desconectado Dino

  • Miembro Junior
  • **
  • Mensajes: 50
  • Karma: +0/-45
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #17 en: Noviembre 26, 2020, 03:10:49 am »
me funciona bien en canales pequeños, pero cuando estoy en un canal grande y un usuario repite la frase, se salta la primera advertencia y manda directo la segunda advertencia, ese detalle sucede rara vez cuando los usuarios son mas de 120usuarios en linea..

Desconectado Dino

  • Miembro Junior
  • **
  • Mensajes: 50
  • Karma: +0/-45
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #18 en: Enero 09, 2021, 04:11:00 am »
funciona bien perfectamente...
pero cuando entro a un canal con mas de 200 usuarios y soy @
de ratos no lanza la primera advertencia lanza directa la segunda????? no entiendo y recivo muchos reclamos...
al paracer la secuencia lectura cuando son varios nicks se mezcla y por eso lo lanza directo a la segunda omitiendo en algunos casos la
primer advertencia ... eso en canales grande con mas de 200 usuarios activos reales.

Desconectado Quetzalcoatl

  • Miembro de pleno derecho
  • ***
  • Mensajes: 201
  • Karma: +241/-2
  • HipercomputoHipermegared
    • elchatirc
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #19 en: Enero 09, 2021, 04:55:57 am »
Ese remoto tiene dos variables una donde guarda si el nick esta advertido y otra el ultimo texto, quizas es por eso que en canales grandes donde hay varia afluencia pueda existir un fallo, lo ideal es lo que habia dicho Cadaver antes, si no mal recuerdo tambien posteo el código de un remote similar donde se evaluan tres frases distintas dichas por un usuario, en donde se usa una sola variable por cada usuario en el canal, lo que de entrada evita la a advertencias equivocadas al mezclarse nicks. Lo ideal para mi seria recrear el código desde cero y usar hashtables para evitar problemas en variables ya que se dejarían de usar y tener un mejor control en cuanto a las advertencias, frases repetidas y el contador.

Cabe notar que yo no hice el código que usas Dino, solo me base en el que se coloco que se había dicho que si funcionaba que solo requería unas modificaciones.

Pero vale la pena buscar el código que posteo cadaver(el cual no esta en este hilo de post, si no en uno previo), no lo he probado pero la estructura que el uso en su programación es muy buena o rehacerlo como mencione usando hashtables.

Desconectado Dino

  • Miembro Junior
  • **
  • Mensajes: 50
  • Karma: +0/-45
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #20 en: Enero 11, 2021, 01:19:50 am »
faltaria un depurador que borre los temp que guardo para comprobar que los borre despues pasado los 5 minutos en lo que guardo
Código: [Seleccionar]
%_cuenta
%NickRepite
como esas son las variantes con la que guarda el nick y canal mas la palabra entonces seria bueno un depurador que los borre pasado
ya los 5 minutos en los cuales los guardo mediante -u300..  esa es una solucion que veo factible un depurador amigo quetzalcoalt
el codigo de cadaver es sencillo y se dispara por mas que el usuario deje de lanzar la palabra repetida cuando intercala una palabra que no es repetida igual le da ban..

Desconectado hank

  • Novato
  • *
  • Mensajes: 19
  • Karma: +0/-8
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #21 en: Enero 12, 2021, 02:41:22 pm »
Buenas tardes.

Seria bueno para todos, que pusiera el addon completo.

¿no creeis?

Saludos.

Desconectado Cadaver

  • Miembro de pleno derecho
  • ***
  • Mensajes: 124
  • Karma: +152/-3
  • Sexo: Masculino
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #22 en: Enero 12, 2021, 05:39:26 pm »
Bueno pero que complicación con las repeticiones ya habiendo muchos por ahí funcionales o incluso el de IRcap que todos usan, les dejo el código que puse desde el inicio modificado:

Código: [Seleccionar]
on *:TEXT:*:#: {
  if ($nick isreg $chan) && ($me isop $chan) {
    if (%flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ]) && ($md5($strip($1-)) == %flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ]) {
      inc -u500 $+(%,flood.,$chan,.nick.,$nick)
      if (%flood. [ $+ [ $chan ] $+ .nick. $+ [ $nick ] ] == 2) { msg $chan AVISO 1 }
      if (%flood. [ $+ [ $chan ] $+ .nick. $+ [ $nick ] ] == 3) { msg $chan AVISO 2 }
      if (%flood. [ $+ [ $chan ] $+ .nick. $+ [ $nick ] ] == 4) { ban -u120 $chan $address($nick,2) | kick $chan $nick Razon del KICK | unset $+(%,flood.,$chan,.txt.,$nick) }
    }
    if (!%flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ]) { set -u500 %flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ] $md5($strip($1-)) | halt }
    if (%flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ]) && ($md5(strip($1-)) != %flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ]) { set -u500 %flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ] $md5($strip($1-)) | unset $+(%,flood.,$chan,.txt.,$nick) | halt }
  }
}

Cable aclarar que si el usuario cambia el texto por otro reiniciara el conteo. ¿Qué se recomienda? Acortar los tiempos de las variables se quedo en 500 porque así lo pidieron desde un inicio pero vamos quieren que sea EXCESO de REPETICIONES por decir 3 holas en 10 minutos pues como que no va, EXCESO de REPETICIONES 5 en 1 minuto  o menos y eso ya es exagerado.
« última modificación: Enero 12, 2021, 05:47:37 pm por Cadaver »

Desconectado hank

  • Novato
  • *
  • Mensajes: 19
  • Karma: +0/-8
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #23 en: Enero 13, 2021, 04:19:48 pm »
Hola.

Muchas gracias!

Desconectado Dino

  • Miembro Junior
  • **
  • Mensajes: 50
  • Karma: +0/-45
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #24 en: Enero 22, 2021, 03:35:29 am »
   Cadaver
tu codigo no funciona muy bien que digamos despues de 5 o 6 repeticiones recien advierte trate de cambiar el inc de 500 a 300 igual tarda en reconocer una palabra repetida
encambio el addons que pusimos arriba ese si funciona muy bien el detalle es solo que en canales grandes con mas de 200 usuarios ahi salta la primer advertencia y lanza la segunda pero eso sucede rara vez..

Desconectado Cadaver

  • Miembro de pleno derecho
  • ***
  • Mensajes: 124
  • Karma: +152/-3
  • Sexo: Masculino
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #25 en: Febrero 03, 2021, 07:20:50 pm »
Corregido:

Código: [Seleccionar]
on *:TEXT:*:#: {
  if ($nick isreg $chan) && ($me isop $chan) {
    if (!%flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ]) { set -u500 %flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ] $md5($strip($1-)) | inc -u500 $+(%,flood.,$chan,.nick.,$nick) | halt }
    if (%flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ]) && ($md5($strip($1-)) != %flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ]) { set -u500 %flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ] $md5($strip($1-)) | unset %flood. [ $+ [ $chan ] $+ .nick. $+ [ $nick ] ] | inc -u500 $+(%,flood.,$chan,.nick.,$nick) | halt }
    if (%flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ]) && ($md5($strip($1-)) == %flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ]) {
      inc $+(%,flood.,$chan,.nick.,$nick)
      if (%flood. [ $+ [ $chan ] $+ .nick. $+ [ $nick ] ] == 2) { msg $chan AVISO 1 }
      if (%flood. [ $+ [ $chan ] $+ .nick. $+ [ $nick ] ] == 3) { msg $chan AVISO 2 }
      if (%flood. [ $+ [ $chan ] $+ .nick. $+ [ $nick ] ] == 4) { ban -u120 $chan $address($nick,2) | kick $chan $nick Razon del KICK | unset %flood. [ $+ [ $chan ] $+ .txt. $+ [ $nick ] ] | unset %flood. [ $+ [ $chan ] $+ .nick. $+ [ $nick ] ] }
    }
  }
}
« última modificación: Febrero 03, 2021, 07:33:11 pm por Cadaver »

Desconectado Dino

  • Miembro Junior
  • **
  • Mensajes: 50
  • Karma: +0/-45
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #26 en: Abril 10, 2021, 07:04:18 am »
gracias cadaver me funciona de maravilla
pero lo estube provando el detalle es que hay segundos a veces vuelve a saltar algunos nicks que repite una pregunta, pero esto solo sucede en canales grandes con usuarios mayores a de 200 nick en lineas, al parecer algo se traba o se interrumpe momentaneamente y luego continua normal o hay ratos que salga la primer pregunta y directo la envia a la segunda advertencia.. gracias por tu codigo de todas formas, y eso solo sucede rara vez pero sucede.

Desconectado jeccopy

  • Novato
  • *
  • Mensajes: 14
  • Karma: +0/-3
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #27 en: Junio 30, 2021, 01:15:29 pm »
esta bueno ese addons? ya lo tienen operativo? si lo pueden poner completo .. se los agradeceriaaa ... desde ya muchas gracias

Desconectado

  • Novato
  • *
  • Mensajes: 2
  • Karma: +0/-6
Re:Tengo un remote que es anti repeticiones con advertencia
« Respuesta #28 en: Julio 10, 2021, 05:38:06 am »